Info

How to adventure

This is an interactive fiction/adventure game, where people can send new scenes to be added from time to time, you can explore the world at your own pace and discover fun interactions.

You can skip a scene to the paths if you're not interested in going trough it again (though you might miss paths in the scene).

If you get stuck or want to go back to the start, there's the '(re)start' button.

How to submit a scene

Still under construction...

Send a text in the format:

- submission (only for the submission/comment box to diferentiate it)
- json {
    <entry json>
}
- scene {
    <scene ink code>
}

to the submissions area, my email or discord.

What I recomend you to use for writting: Inky, the ink editor, link at the bottom of the page.

guidelines I'm doing this out of nicenes, please don't be an a-hole

  • The scene must be self contained code-wise
  • Your ink code can't have more than 250 lines, lines must be 200 characters max
  • Please don't abuse # CHANGE_COLOR and # INVERT_COLOR
  • You can jump to other scenes, but, put a "# CLEAR \n ~ last_room = curr_room \n # PUSH_HIST", and know the address might not work
  • At some point your scene must finish to the exits section (-> r_end), no infinite loops you can't get out of or all dead ends
  • No exploiting to try breaking the game or site
  • Don't claim too many scenes (3+) at once, please

ink code example For more information on how to write ink, go to their site (link at bottom of this page)

You are bored at home, but <em>you want</em> to go on an adventure!

// * is a one time choice (once you chose it, it disappears)
* [Watch a show] -> w_show
// The option will only appear if you've visited the 'l_time' stitch
* {l_time} [Have a bath] -> bath
// + is multiple uses
+ [Go outside]
//  Use the CLEAR tag to clear the screen
    # CLEAR
    # INVERT_COLOR
    -> outside
+ [Look at the time] -> l_time
* {bath and w_show} [Go to sleep] -> sleep

// A stitch, a piece of the text you can jump to
= l_time
// Text betwen {} separated with | changes every time you see the passage
// ~ at the start to make it random, & to loop and wrap around options
// It can be nested
It's {quarter to nine|nine o'clock}, time to have a {~bath|shower}
-> r_main

= w_show
You watch TV
-> r_main

= bath
You have a nice and relaxing {&bath|shower} to get ready for the day
-> r_main

= sleep
// Use these to change colours
~ room_bg_color = "\#000000"
~ room_fg_color = "\#ffffff"
# CHANGE_COLOR
# RESET_COLOR
You are already tired for the day.
You go to sleep for the day, it's a good and comfy bed
// Jump to this knot to put an end screen
-> a_room_end

= mailbox
There is a leaflet inside, it reads:

"WELCOME TO A COMMUNITY ADVENTURE!"
-> outside

= outside
It's a beautiful day outside, the breeze is calm
and pleasant, you hear the birds and insects singing
their nature songs.

* [Options can be]
    ** Nested
        *** Within
        *** [Different] Woah
        ---
    ** Levels
    --
* "Yey!"
-
// Only show text if you haven't visited the 'mailbox' stitch
{not mailbox:You see your mailbox has something for you.}

+ [Continue]
+ [Get back inside]
    # CLEAR
    # INVERT_COLOR
    -> r_main
* {not mailbox} [Check mailbox] -> mailbox
// If the choice doesn't have a jump, continue to the text after the '-'
-

Because each scene should be self contained, you are only able to set temp vars, so there are a few global vars that you can use to store information for the entire scene (they are reset at = r_end), you can use them for storing any information.
(hp_ = 100, xp_ = 0, gd_ = 0, md_ = "", nm_ = "", num_(0 to 3)_ = 0, txt_(0 to 3)_ = 0)

entry json Keep max_exits at maximum 3 and minimum 1
The text, is the ink code you'll send, as a separate file

{
    "code"      :"scene_code", 
    "title"     :"My title", 
    "fg_color"  :"#ffffff", 
    "bg_color"  :"#000000", 
    "descript"  :"Some quick description of the scene", 
    "by"        :"Your Name",
    "text"      :"leave empty",
    "exits"     :[ "Exit 1 name", "Exit 2 name", "Exit 3 name"],
    "max_exits" :3
}

test environment code Some boilerplate code for you to test your scene on inky or inklecate (the tags won't work with these)

VAR last_room = -> room_000000
VAR curr_room = -> room_000000
VAR room_bg_color = ""
VAR room_fg_color = ""

VAR hp_ = 100
VAR XP_ = 0
VAR gd_ = 0
VAR md_ = ""
VAR nm_ = ""
VAR num_0 = 0
VAR num_1 = 0
VAR num_2 = 0
VAR num_3 = 0
VAR txt_0 = ""
VAR txt_1 = ""
VAR txt_2 = ""
VAR txt_3 = ""

->room_000000
== room_000000
= r_main

// Your code goes here

->r_end
= r_end
->END

Notice: This is perpetually half-baked quality software, don't expect it to be too polished!


Powered by Ink.

Comments / Submissions
HTML Comment Box is loading comments...